plugins {
    id 'fabric-loom' version '1.10.5' apply false
//    id 'maven-publish' apply false

    id 'com.replaymod.preprocess' version '9d21b334a7'

    id 'com.github.johnrengelman.shadow' version '8.1.1' apply false
}

version = project.mod_version
group = project.maven_group

preprocess {
    strictExtraMappings.set(false)

    def mc12104 = createNode("1.21.4", 1_21_04, "")
    def mc12105 = createNode("1.21.5", 1_21_05, "")
    def mc12106 = createNode("1.21.6", 1_21_06, "")
    def mc12107 = createNode("1.21.7", 1_21_07, "")
    def mc12108 = createNode("1.21.8", 1_21_08, "")

    mc12108.link(mc12107, file("versions/mapping_12108_12107.txt"))
    mc12107.link(mc12106, file("versions/mapping_12107_12106.txt"))
    mc12106.link(mc12105, file("versions/mapping_12106_12105.txt"))
    mc12105.link(mc12104, file("versions/mapping_12105_12104.txt"))
}

tasks.register('buildAndGather') {
    subprojects {
        dependsOn project.tasks.named('build').get()
    }
    doFirst {
        println 'Gathering builds'
        def buildLibs = {
            p -> p.buildDir.toPath().resolve('libs')
        }
        delete fileTree(buildLibs(rootProject)) {
            include '*'
        }
        subprojects {
            copy {
                from(buildLibs(project)) {
                    include '*.jar'
                    exclude '*-dev.jar', '*-sources.jar', '*-shadow.jar'
                }
                into buildLibs(rootProject)
                duplicatesStrategy DuplicatesStrategy.INCLUDE
            }
        }
    }
}